منتديات نهران • مشاهدة الموضوع - معادلات زياد علاوي الفلكية لكل مبرمج

 

 

 

 



إرسال موضوع جديد الرد على الموضوع

 [ 3 مشاركة ] 

 
الكاتب رسالة

 عنوان المشاركة: معادلات زياد علاوي الفلكية لكل مبرمج

مشاركةمرسل: الأحد يوليو 06, 2014 9:41 pm 

معلومات العضو

المشرف العام

صورة العضو الشخصية

إحصائيات العضو


اشترك في: الخميس فبراير 18, 2010 9:29 pm

مشاركات: 7155

غير متصل

برامج ومعادلات زياد علاوي نفعتني كثيرا في البرمجة وانا ابحث بها حاليا لصناعة برنامج نور النجوم من جديد ولكن هذه المرة على الجافا ان شاء الله لكي يعمل على الموبايلات
اشكر الاخ زياد بشدة على هذه الدرر



بسم الله الرحمن الرحيم
البرنامج رقم 1...
برنامج تحويل النظام العشري الى ستيني...

CLS
INPUT "Hour or Angle:"; X
N1 = INT(X)
N2 = INT((X - N1) * 60)
N3 = INT(((X - N1) * 60 - N2) * 60)
PRINT N1; N2; N3
END

علاوي...
__________________

البرنامج رقم 2...
برنامج تحويل النظام الستيني الى عشري...

CLS
INPUT "Hour:"; H
INPUT "Minute:"; N
INPUT "Second:"; S
X = H + (N + S / 60) / 60
PRINT "Hour or Angle:"; X
END

علاوي...

البرنامج رقم 3...
برنامج حساب عدد الايام لتاريخ معين...

CLS
INPUT "Year:"; Y
INPUT "Month:"; M
INPUT "Day:"; D
INPUT "Hour:"; H
INPUT "Minute"; N
B = 0
IF 10000 * Y + 100 * M + D > 15821015 THEN B = 2 - INT(Y / 100) + INT(Y / 400)
M = M + 1
IF M < 4 THEN M = M + 12: Y = Y - 1
DD = INT(365.25 * Y) + INT(30.6 * M) + D + B + (H - Z + N / 60) / 24 - 429
PRINT "Days Since 1/1/1 AD:"; DD
PRINT " Days Since 1/1/2001 AD:"; DD - 730487
END

علاوي...

البرنامج رقم 4...
برنامج لحساب التقويم الميلادي لعدد من الايام (عكس برنامج 3)...

CLS
INPUT "Days:"; DD
F = DD - INT(DD)
I = DD - F
IF I > 577736 THEN A = INT((I + 306) / 36524.25): I = I + A - INT(A / 4) - 2
Y = INT((I + 306) / 365.25)
C = I - INT(Y * 365.25) + 429
G = INT(C / 30.6001)
M = G - 1: IF G > 13 THEN M = M - 12
IF M < 3 THEN Y = Y + 1
D = C - INT(G * 30.6001)
PRINT "Date:"; Y; M; D; F * 24
END

علاوي...

البرنامج رقم 5...
برنامج تحويل الوقت المدني الى الوقت النجمي...

CLS
REM Converts the Local Time to Siderial Time
INPUT "Year:"; Y
INPUT "Month:"; M
INPUT "Day:"; D
INPUT "Hour:"; H
INPUT "Minute"; N
INPUT "Zone:"; Z
INPUT "Long.:"; L
B = 0
IF 10000 * Y + 100 * M + D > 15821015 THEN B = 2 - INT(Y / 100) + INT(Y / 400)
M = M + 1
IF M < 4 THEN M = M + 12: Y = Y - 1
DD = INT(365.25 * Y) + INT(30.6 * M) + D + B - 730916
D = DD + 36890.5
T = H + N / 60
ST = 6.646065552# + L / 15 + .00273790854586# * (24 * D + T - Z) + T - Z
ST = ST - INT(ST / 24) * 24
N1 = INT(ST)
N2 = INT((ST - N1) * 60)
N3 = INT(((ST - N1) * 60 - N2) * 60)
PRINT "Siderial Hour:Min:Sec"; N1; N2; N3
END

علاوي...
__

البرنامج رقم 6...
برنامج حساب الوقت المدني من الوقت النجمي (عكس البرنامج 5)...

CLS
REM Converts the Siderial Time to Local Time
INPUT "Year:"; Y
INPUT "Month:"; M
INPUT "Day:"; D
INPUT "Sid. Hr.:"; H
INPUT "Sid. Min.:"; N
INPUT "Zone:"; Z
INPUT "Long.:"; L
B = 0
IF 10000 * Y + 100 * M + D > 15821015 THEN B = 2 - INT(Y / 100) + INT(Y / 400)
M = M + 1
IF M < 4 THEN M = M + 12: Y = Y - 1
DD = INT(365.25 * Y) + INT(30.6 * M) + D + B - 730916
D = DD + 36890.5
T = H + N / 60
LT = T - (6.646065552# + L / 15 + .00273790854586# * (24 * D - Z) - Z)
LT = LT - INT(LT / 24) * 24
LT = LT * .9972695671296296#
N1 = INT(LT)
N2 = INT((LT - N1) * 60)
N3 = INT(((LT - N1) * 60 - N2) * 60)
PRINT "Local Time:"; N1; N2; N3
END

علاوي...

البرنامج رقم 7...
برنامج مطالع التسيير...

CLS
REM Calculates the Regresion Ascensions
PI = 57.29577951#
INPUT "Ecliptic Longitude:", L
L = L / PI
INPUT "Ecliptic MidHeaven:", M
M = M / PI
INPUT "Geographic Lattitude:", D
CE = COS(23.46 / PI)
TE = TAN(23.46 / PI)
SD = SIN(D / PI)
A = ATN(TAN(L) * CE)
IF COS(L) < 0 THEN A = A + 180 / PI
IF A < 0 THEN A = A + 360 / PI
B = ATN(TAN(M) * CE)
IF COS(M) < 0 THEN B = B + 180 / PI
IF B < 0 THEN B = B + 360 / PI
SA = SIN(A)
I = 0
1 X = SD * SIN(A - B - I)
J = ATN(SA * TE * X / SQR(1 - X * X))
J = J / SQR(1 - J * J)
IF J <> I THEN I = J: GOTO 1
R = (A - I) * PI
PRINT "Regression:"; R
END

علاوي...
__________________

البرنامج رقم 8...
برنامج استخراج الميل والمطلعين الفلكي والبلدي لأي نقطة على مدار البروج...

CLS
PI = 57.29577951#
INPUT "Ecliptic Longitude:"; L
INPUT "Lattitude:"; T
L = L / PI
T = T / PI
E = 23.45 / PI
A = ATN(TAN(L) * COS(E)) * PI
IF COS(L) < 0 THEN A = A + 180
IF A < 0 THEN A = A + 360
D = SIN(L) * SIN(E)
D = ATN(D / SQR(1 - D ^ 2)) * PI
S = SIN(A / PI) * TAN(T) * TAN(E)
C = A - ATN(S / SQR(1 - S ^ 2)) * PI
PRINT "Astro. Decl.:"; D
PRINT "Astro. Ascen.:"; A
PRINT "Local Ascen.:"; C
END

علاوي...
_______

البرنامج رقم 9...
برنامج حساب الوقت النجمي لشروق وغروب جرم معين في موقع معين...

CLS
PI = 57.29577951#
INPUT "Decl:"; D
INPUT "RA:"; R
INPUT "Lat:"; T
D = D / PI
T = T / PI
K = -TAN(D) * TAN(T)
IF K < -1 THEN PRINT "Never Sets.": END
IF K > 1 THEN PRINT "Never Rises.": END
C = ATN(SQR(1 - K ^ 2) / K)
C = C * PI / 15
IF C < 0 THEN C = C + 12
RT = R - C
RT = RT - INT(RT / 24) * 24
ST = R + C
ST = ST - INT(ST / 24) * 24
PRINT "Siderial Rise Time:"; RT
PRINT "Siderial Set Time:"; ST
END

البرنامج رقم 10...
برنامج معادلة كبلر لحساب الحصة الحقيقية للكوكب من الحصة الوسيطة...

CLS
PI = 57.29577951#
INPUT "Mean Anomaly:"; M
INPUT "Eccentricity:"; E
M = M / PI
T = M
1 D = (T - E * SIN(T) - M) / (1 - E * COS(T))
IF ABS(D) > .000001 THEN T = T - D: GOTO 1
R = 2 * ATN(SQR((1 + E) / (1 - E)) * TAN(T / 2)) * PI
PRINT "True Anomaly:"; R
END

علاوي...
_______

البرنامج رقم 11...
برنامج حساب موقع الشمس على مدار البروج وبعد الأرض عنها...

CLS
INPUT "Days:"; DD
PI = 57.29577951#
DEF FNANG (A, B, C, D, PI) = (A + 360 * B * D + C * D * D - INT((A + 360 * B * D + C * D * D) / 360) * 360) / PI
D = (DD + 36890.5) / 365.25
LS = FNANG(279.69668#, 1.000021359#, 3.025E-08, D, PI)
MS = FNANG(358.47583#, .9999736042#, 1.5E-08, D, PI)
E = .01675104# - 4.18E-07 * D
A1 = FNANG(153.23, .6255209472#, 0, D, PI)
A2 = FNANG(216.57, 1.251041894#, 0, D, PI)
A3 = FNANG(312.69, .9156766028#, 0, D, PI)
A4 = FNANG(350.74, 12.36853095#, 1.44E-07, D, PI)
A5 = FNANG(231.19, .0561111111#, 0, D, PI)
T = MS
1 D = (T - E * SIN(T) - MS) / (1 - E * COS(T))
IF ABS(D) > .000001 THEN T = T - D: GOTO 1
NU = 2 * ATN(SQR((1 + E) / (1 - E)) * TAN(T / 2))
L = (NU + LS - MS) * PI + .00134 * COS(A1) + .00154 * COS(A2) + .002 * COS(A3) + .00179 * SIN(A4) + .00178 * SIN(A5)
L = L - INT(L / 360) * 360
G = INT(L)
N = INT((L - G) * 60)
S = INT((L - G - N / 60) * 60)
R = (1 - E ^ 2) / (1 + E * COS(NU))
PRINT "Solar Longitude:"; G; N; S
PRINT " Solar Distance:"; R
END

علاوي...
__


التوقيع

وعلامات وبالنجم هم يهتدون


تويتر monadhl_mosa@
فيس بوك https://www.facebook.com/nehranastrology
بريد الموقع nehran@n2007.com
بريدي الشخصي monadhl25@gmail.com
واتساب + فايبر + تليغرام 00962796033153



أعلى

 يشاهد الملف الشخصي  

رد مع اقتباس  

 عنوان المشاركة: Re: معادلات زياد علاوي الفلكية لكل مبرمج

مشاركةمرسل: السبت يوليو 12, 2014 8:48 am 

معلومات العضو

نجم يتألق

صورة العضو الشخصية

إحصائيات العضو


اشترك في: الأربعاء يونيو 02, 2010 6:02 pm

مشاركات: 6

غير متصل

أخي مناضل .. كريم على طول .
شكرا جزيلا



أعلى

 يشاهد الملف الشخصي  

رد مع اقتباس  

 عنوان المشاركة: Re: معادلات زياد علاوي الفلكية لكل مبرمج

مشاركةمرسل: الأحد سبتمبر 20, 2015 9:01 pm 

معلومات العضو

نجم يتألق

صورة العضو الشخصية

إحصائيات العضو


اشترك في: الخميس سبتمبر 17, 2015 9:17 pm

مشاركات: 32

غير متصل

ما هي معادلة المنازل القمرية وحلول الشمس والقمر فيها ؟
رأيت شخص وضع منازل القمر للقمر في برنامج الاكسل وهي بها معالادات لا ادري كيف جاء بها ويقول انه معتمد على برنامج زيت وهو جميل ومرتب



أعلى

 يشاهد الملف الشخصي  

رد مع اقتباس  

عرض مشاركات سابقة منذ:  مرتبة بواسطة  

إرسال موضوع جديد الرد على الموضوع

 [ 3 مشاركة ] 


جميع الأوقات تستخدم GMT + ساعتين [ DST ]
اليوم هو الأحد يونيو 16, 2019 7:29 pm


الموجودون الآن

المستخدمون المتصفحون لهذا المنتدى: لا يوجد أعضاء مسجلين متصلين و 0 زائر/زوار


لا تستطيع كتابة مواضيع جديدة في هذا المنتدى
لا تستطيع كتابة ردود في هذا المنتدى
لا تستطيع تعديل مشاركاتك في هذا المنتدى
لا تستطيع حذف مشاركاتك في هذا المنتدى
لا تستطيع إرفاق ملف في هذا المنتدى


الانتقال الى:  
cron
Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group
Translated by phpBBArabia | Design tansformation:bbcolors
  تصميم الستايل علاء الفاتك   http://www.moonsat.net/vb